<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="2.0">

  <xsl:output indent="yes"/>

  <xsl:template match="/">
    <konference>
      <název>MS Fest 2012</název>
      <místo>FEL ČVUT Dejvice</místo>
      <xsl:for-each select="Agenda/Day/Slot/Session">
        <přednáška datum="{../../@Date}" začátek="{../@TimeBegin}:00" konec="{../@TimeEnd}:00" 
                   místnost="{../../Track[current()/@TrackIndex + 1]/@Location}">
          <název><xsl:value-of select="@Title"/></název>
          <sekce><xsl:value-of select="../../Track[current()/@TrackIndex + 1]/@Name"/></sekce>
          <xsl:analyze-string select="@Speaker" regex="^(.+)\s+\((.+)\)\s*$">
            <xsl:matching-substring>
              <autor>
                <jméno><xsl:value-of select="regex-group(1)"/></jméno>
                <organizace><xsl:value-of select="regex-group(2)"/></organizace>  
              </autor>                  
            </xsl:matching-substring>
            <xsl:non-matching-substring>
              <autor>
                <jméno><xsl:value-of select="."/></jméno>
              </autor>                  
            </xsl:non-matching-substring>            
          </xsl:analyze-string>
          <popis><xsl:value-of select="normalize-space(.)"/></popis>        
        </přednáška>
      </xsl:for-each>
    </konference>
  </xsl:template>
  
</xsl:stylesheet>