Prev 4 / 22Next 

Zpracování dokumentu pomocí šablon

  • základní, byť často nepochopený princip XSLT

  • automatický průchod dokumentem a volání šablon dovoluje zpracovávat dokumenty se složitou a nepravidelnou strukturou

Příklad 1. Použití šablon – sablony.xsl

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="2.0">

<xsl:template match="konference">
  <html>
    <head>
      <title>Program <xsl:value-of select="název"/></title>
      <style>
        body { font-family: Calibri, sans-serif; }
        h1 { text-align: center; background-color: navy; color: yellow; }
        h2 { color: navy; }
      </style>
    </head>
    <body>
      <xsl:apply-templates/>
    </body>
  </html>
</xsl:template>
  
<xsl:template match="konference/název">
  <h1><xsl:apply-templates/></h1>
</xsl:template>

<xsl:template match="místo"/>  
  
<xsl:template match="přednáška">
  <xsl:apply-templates/>
  <xsl:if test="following-sibling::přednáška">
    <hr/>
  </xsl:if>
</xsl:template>
  
<xsl:template match="název">
  <h2><xsl:apply-templates/></h2>
</xsl:template>

<xsl:template match="autor">
  <p>
    <i>
      <xsl:value-of select="jméno"/>
      <xsl:if test="organizace">
        (<xsl:value-of select="organizace"/>)
      </xsl:if>
    </i>
  </p>
</xsl:template>

<xsl:template match="sekce"/>

<xsl:template match="popis">
  <p><xsl:apply-templates/></p>
</xsl:template>

</xsl:stylesheet>

Copyright © 2012 Jiří Kosek Prev Next